6 REM AUTHOR AND SOURCE UNKNOWN
100 REM ***************************
110 REM *                         *
120 REM *     SCRAMBLED WORD      *
130 REM *                         *
140 REM *    KID-PROOFED BY QJ    *
160 REM *                         *
170 REM ***************************
180 :
190 :
200 PRINT"[147]"TAB(8)"[164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164]"
210 PRINTTAB( 8)"A SCRAMBLED WORD GAME"
220 DIM B$(20),A(20)
230 RESTORE
240 A$=""
250 B$=""
260 C$=""
270 FOR Z = 1 TO 20
280 A(Z) = 0
290 NEXT Z
300 A =INT(30*RND(TI)+1)
310 FOR B=1 TO A
320 READ A$
330 IFA$="END" THEN RESTORE: B=B-1
340 NEXT B
350 C=LEN(A$)
360 FOR E=1 TOC
370 D=INT(C*RND(TI)+1)
380 IF A(D)=1 THEN 370
390 B$(E)=MID$(A$,D,1)
400 B$=B$+B$(E)
410 A(D)=1
420 NEXT E
430 IF A$=B$ THEN 360
440 PRINT"UNSCRAMBLE:    ";:GOSUB2000:PRINT B$:WW=0
445 PRINT""
450 PRINT"     WAS MEINST DU ? ";
460 GOSUB1060
470 PRINT:PRINT
480 C$=IN$
490 IFA$=C$ THEN 560
500 GOTO 530
510 GOSUB3100:WW=WW+1:IFWW<3THENGOSUB3000 :GOTO445
515 PRINT"  RICHTIG IST  : "A$:PRINT
520 GOTO 580
530 W=W+1:GOTO510
560 PRINT"RICHTIG!!":PRINT
570 R=R+1
580 PRINT"SCORE:  RICHTIG"R"   FALSCH"W:
585 PRINT"[164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164][164]"
590 PRINT"NOCH EIN WORT?  (J/N)[146]";
600 GETQQ$:IFQQ$<>"J"ANDQQ$<>"N"THEN600
610 IFQQ$="J" THEN PRINT"[147]":GOTO240
650 PRINT"[147]DEINE ANTWORTEN:"
660 T=W+R
670 X=INT(R/T*100+.5)
680 Y=INT(W/T*100+.5)
690 PRINT
700 PRINTX"% RICHTIG       "Y" % FALSCH"
710 PRINT
720 END
740 DATA HOBBY,BLUME,FENSTER,MASCHINE
750 DATA BUCH,SCHATTEN,SONNIG,LESEN
760 DATA TIER,GIRAFFE,ZEBRA,KATZE
770 DATA SCHULE,FLASCHE,TASSE,DISKETTE
780 DATA REGEN,SCHNEE,FRIEREN,SCHWITZEN
790 DATA MAGISCH,WOLKIG,NEBEL,GEWITTER
800 DATA SCHUHE,HOSE,HEMD,SOCKEN
810 DATA FREUND,DICHTER,AGENT,KAMEL
820 DATA ZIEGE,SENDER,EINLADUNG,MAUS
830 DATA WEIN,BIER,DROGE,KAFFEE
840 DATA CHOR,TABAK,STAHL,LASTER
850 DATA HEUCHLER,HEUTE,HIMMEL,HAUSHUND
860 DATA GENETIK,GENIESSEN,ZUCKER,BROT
870 DATA GRENZE,HUMOR,LUSTIG,TRAURIG
880 DATA SINNLOS,SCHMERZ,FREUDE,WAGNIS
890 DATA EMPFINDLICH,SENSIBEL,EMPFANG,DIGITAL
900 DATA LINEAR,DIVISION,DOKTOR,DOKUMENT
910 DATA BLINDDARM,BLASEN,WEHEN,BLOND
920 DATA CARTRIDGE,QUAKEN,BLENDEN,ARBEIT
930 DATA NUMMER,NUSSBAUM,OBHUT,OBERARM
940 DATA OBSKUR,GESPENST,OKTOBER,JANUAR
950 DATA ANFANG,PISTAZIE,RAHMEN,RASSEL
960 DATA RASEN,RASSE,RANZEN,RASIEREN
970 DATA ALBUM,SCHADEN,SAUEREI,SAUBER
980 DATA ILTIS,SCHAF,GRIZZLY,SINNBILD
990 DATA ASKET,SILBER,GOLD,ALUMINIUM
1000 DATA SIEGER,TRIKOT,TRIPPELN,TUBE
1010 DATA FUTTER,NICKEL,GIFTIG,TROTTEL,REGENBOGEN,TRUMPF
1020 DATA NERVEN,TROST,HYMNE,FAKTOR
1030 DATA STUHL,TISCH,BETT,KISSEN,WAHL
1040 DATA ESEL,AFFE,VERWEIS,VERWANDTE,VERZEHR,INFUSION
1050 DATA END,END
1060 REM
1070 REM CURSOR INPUT ROUTINE...PET USERS CLUB VOL 1,#6...QJ...9/1/79
1080 CR$=CHR$(13)
1090 REM SET FL=1 FOR OLD STYLE PETS.
1100 IN$=" ":ZT=TI:ZC=2:ZD$=CHR$(20)
1110 GETZ$:IFZ$<>""THEN1140
1120 IFZT<=TITHENPRINTMID$(" [166]",ZC,1);"[157]";:ZC=3-ZC:ZT=TI+15
1130 GOTO1110
1140 Z=ASC(Z$):ZL=LEN(IN$):IF(ZAND127)<32THENPRINT" [157]";:GOTO1180
1150 IFFLAND(ZAND127)>64AND(ZAND127)<91THENZ$=CHR$((Z+128)AND255)
1160 IFZL>254THEN1110
1170 IN$=IN$+Z$:PRINTZ$;ZD$;Z$;
1180 IFZ=13THENIN$=MID$(IN$,2):PRINTCR$;:RETURN
1190 IFZ=20ANDZL>1THENIN$=LEFT$(IN$,ZL-1):PRINT"[157]";:          GOTO1110
1200 IFZ=141THENZ$=CHR$(-20*(ZL>1)):FORZ=2TOZL:PRINTZ$;:NEXTZ:GOTO1100
1210 GOTO1110    
2000 PRINT"[145][176]";:FORX=1TOLEN(B$):PRINT"[192]";:NEXT:PRINT"[174]"
2010 PRINTSPC(15) "[221]";:FORX=1TOLEN(B$):PRINT" ";:NEXT:PRINT"[221]"
2020 PRINTSPC(15) "[173]";:FORX=1TOLEN(B$):PRINT"[192]";:NEXT:PRINT"[189]"
2030 PRINTTAB(16)"[145][145]";
2040 RETURN
3000 FORXX=1TO500:NEXT
3010 PRINT""SPC(19)"                   ":RETURN
3100 PRINTSPC(19)"SORRY!!";: FORXX=1TO500:NEXT:PRINT"[157][157][157][157][157][157][157][157]        ":RETURN